// Moon_rotating_thirdquarter_220px.pov
#version 3.7;
#include "colors.inc"

global_settings { assumed_gamma 1 }

camera { location <0, 0, -220> look_at <0, 0, 0> up 0.00526 right 0.00526 }

light_source {
    <2,0,0> * 200
    color White
    parallel
    point_at <0,0,0>
}

// use true 3D surface
#include "functions.inc"
#declare ele=function{
    pigment{
        image_map{
            jpeg "moon_elevation.jpg" map_type 1 interpolate 2
        }
    }
}

#declare rs=0.006; // ratio of roughness to radius
isosurface {
    function { f_sphere(x,y,z, 1) + rs * (1 - ele(x,y,z).gray) }
    contained_by { sphere {0,1.01} }
    accuracy 0.00001
    max_gradient 1.2
    texture {
        pigment {
            image_map { jpeg "moon_surface.jpg" map_type 1 } }
            finish {
                ambient rgb 0.006*<1,1,1> // space is dark
                diffuse 1.9 // brightness
                brilliance 1.0 // seems most realistic
            }
        }
    scale <1,1,-1>
    rotate <0,-90+360*clock,0>
    translate <0,0,0>
}